SOMME.SI et SOMME.SI.ENS
Le total des ventes de la région Nord, le CA d'un commercial sur le mois de mars, les dépenses supérieures à 500 € : dès qu'un total dépend d'une condition, c'est SOMME.SI.ENS. C'est l'une des fonctions les plus utiles d'Excel, et l'une des plus demandées en entreprise.
Télécharger la fiche PDF gratuiteSans inscription, mise en page prête à imprimer01Définition
SOMME.SI.ENS additionne les valeurs d'une plage pour les seules lignes qui respectent tous les critères indiqués. SOMME.SI fait la même chose avec un seul critère.
02Syntaxe
=SOMME.SI(plage; critère; [somme_plage]) =SOMME.SI.ENS(somme_plage; plage_critères1; critère1; [plage_critères2; critère2]; ...)
Dans SOMME.SI, la plage à additionner est à la fin. Dans SOMME.SI.ENS, elle est au début. Le plus simple est de n'utiliser que SOMME.SI.ENS, même avec un seul critère : une seule syntaxe à retenir.
03Exemples
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Date | Région | Commercial | Montant |
| 2 | 12/01/2026 | Nord | Alice | 1 200 € |
| 3 | 25/01/2026 | Sud | Bruno | 800 € |
| 4 | 03/02/2026 | Nord | Bruno | 2 500 € |
| 5 | 18/02/2026 | Nord | Alice | 600 € |
| 6 | 09/03/2026 | Sud | Alice | 1 900 € |
=SOMME.SI.ENS(D2:D6;B2:B6;"Nord")
=SOMME.SI.ENS(D2:D6;B2:B6;"Nord";C2:C6;"Alice")
=SOMME.SI.ENS(D2:D6;D2:D6;">=1000")
04Écrire les critères
| Critère | Écriture | Ce qu'il retient |
|---|---|---|
| Texte exact | "Nord" | Les cellules égales à Nord, sans tenir compte des majuscules |
| Différent de | "<>Annulé" | Tout sauf Annulé |
| Comparaison | ">500" | Les nombres strictement supérieurs à 500 |
| Contient | "*nord*" | Les textes qui contiennent nord |
| Commence par | "P-1*" | Les textes qui commencent par P-1 |
| Cellule vide | "" | Les cellules vides |
| Cellule non vide | "<>" | Les cellules remplies |
L'étoile * remplace n'importe quelle suite de caractères, le point d'interrogation ? remplace un seul caractère.
05Un critère placé dans une cellule
Pour faire un tableau de synthèse, on écrit le critère dans une cellule et on y fait référence. Avec un opérateur, il faut coller l'opérateur et la cellule avec &.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Date | Région | Commercial | Montant | Région | Total | |
| 2 | 12/01/2026 | Nord | Alice | 1 200 € | Nord | =SOMME.SI.ENS($D$2:$D$6;$B$2:$B$6;F2) | |
| 3 | 25/01/2026 | Sud | Bruno | 800 € | Sud | 2 700 € |
=SOMME.SI.ENS(D2:D6;D2:D6;">="&H1)
06Critères sur des dates
=SOMME.SI.ENS(D2:D6;A2:A6;">="&DATE(2026;2;1);A2:A6;"<"&DATE(2026;3;1))
On encadre la période par deux critères sur la même colonne : à partir du 1er février, et avant le 1er mars. Cela fonctionne quel que soit le nombre de jours du mois.
07Une condition OU
SOMME.SI.ENS combine ses critères avec ET. Pour additionner le Nord ou le Sud, on additionne deux SOMME.SI.ENS :
=SOMME.SI.ENS(D2:D6;B2:B6;"Nord")+SOMME.SI.ENS(D2:D6;B2:B6;"Sud")
08Pièges à éviter
Toutes les plages d'un SOMME.SI.ENS doivent avoir le même nombre de lignes : D2:D6 avec B2:B7 renvoie #VALEUR!. Avec des tableaux structurés, ce risque disparaît.
=SOMME.SI.ENS(D2:D6;D2:D6;>=H1) est refusé. L'opérateur est du texte : ">="&H1.
« Nord » et « Nord » suivi d'une espace sont deux textes différents, et la ligne est ignorée sans prévenir. Nettoyez la colonne avec SUPPRESPACE en cas de doute.
09Questions fréquentes
Comment faire une somme avec plusieurs critères dans Excel ?
SOMME.SI.ENS additionne les valeurs d'une plage pour les seules lignes qui respectent tous les critères indiqués. SOMME.SI fait la même chose avec un seul critère.
Quel est le piège le plus fréquent avec SOMME.SI et SOMME.SI.ENS ?
L'ordre des arguments n'est pas le même. Dans SOMME.SI, la plage à additionner est à la fin. Dans SOMME.SI.ENS, elle est au début. Le plus simple est de n'utiliser que SOMME.SI.ENS, même avec un seul critère : une seule syntaxe à retenir.
La fiche « SOMME.SI et SOMME.SI.ENS » est-elle gratuite ?
Oui. La fiche est en accès libre et gratuit, sans inscription : vous pouvez la lire en ligne et télécharger sa version PDF. Elle fait partie du cours de formules Excel gratuit de mesetudesdecas.fr, qui compte 23 fiches.
Passez de la fiche à la mise en situation
Les études de cas Excel de mesetudesdecas.fr placent vos apprenants face à un vrai besoin d'entreprise : fonctions de recherche, calculs conditionnels, tableaux croisés et tableaux de bord, avec énoncé, corrigé et pas-à-pas du formateur.
Voir les études de cas ExcelToutes les fiches de formules Excel
Voir aussi le cours VBA gratuit
Fiche V1.0 | Dernière mise à jour : 30/10/2026 | Clément Delobel, formateur Excel