Assembler du texte
Prénom et nom dans une seule cellule, une phrase qui reprend un montant, un identifiant fabriqué à partir de plusieurs colonnes : assembler du texte est un besoin de tous les jours. Le plus simple est l'esperluette, mais elle a un piège avec les dates et les nombres.
Télécharger la fiche PDF gratuiteSans inscription, mise en page prête à imprimer01Définition
Concaténer, c'est mettre bout à bout plusieurs textes ou valeurs dans une seule cellule. L'opérateur & suffit dans la plupart des cas.
02L'opérateur &
| A | B | C | |
|---|---|---|---|
| 1 | Prénom | Nom | Nom complet |
| 2 | Alice | Martin | =A2&" "&B2 |
| 3 | Bruno | Leroy | Bruno Leroy |
Le " " ajoute l'espace entre les deux : sans lui, on obtiendrait « AliceMartin ».
="Commande "&A2&" livrée à "&B2
03CONCAT et JOINDRE.TEXTE
=CONCAT(texte1; [texte2]; ...) =JOINDRE.TEXTE(délimiteur; ignorer_vide; texte1; [texte2]; ...)
CONCAT accepte des plages entières : =CONCAT(A2:D2) colle les quatre cellules. JOINDRE.TEXTE ajoute en plus un séparateur entre chaque valeur, et peut ignorer les cellules vides :
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Rue | Complément | CP | Ville | Adresse |
| 2 | 12 rue Nationale | 59000 | Lille | =JOINDRE.TEXTE(", ";VRAI;A2:D2) |
Résultat : « 12 rue Nationale, 59000, Lille », sans virgule en double.
CONCAT et JOINDRE.TEXTE existent à partir d'Excel 2019. L'ancienne fonction CONCATENER fonctionne encore, mais n'accepte pas les plages.
04Garder le format des nombres et des dates
Une date ou un montant perd sa mise en forme dès qu'on l'assemble avec du texte, car Excel utilise la valeur brute. La fonction TEXTE applique un format choisi :
| Formule | Résultat |
|---|---|
="Échéance : "&B2 | Échéance : 46325 |
="Échéance : "&TEXTE(B2;"jj/mm/aaaa") | Échéance : 30/10/2026 |
="Total : "&TEXTE(C2;"# ##0,00 €") | Total : 1 250,00 € |
=TEXTE(B2;"mmmm aaaa") | octobre 2026 |
05Un retour à la ligne dans la cellule
=A2&CAR(10)&B2
CAR(10) est le caractère de saut de ligne. Il ne s'affiche que si la cellule a l'option Renvoyer à la ligne automatiquement (onglet Accueil).
06Pièges à éviter
="1"&"5" donne le texte « 15 », pas le nombre 15 : il ne s'additionne pas. Si vous fabriquez un nombre, convertissez-le avec CNUM, ou multipliez-le par 1.
Pour afficher un guillemet, il faut le doubler : ="Il a dit ""oui""" affiche Il a dit "oui".
Le résultat d'une concaténation reste une formule : si vous supprimez les colonnes d'origine, il disparaît. Pour garder seulement le texte, copiez puis Collage spécial > Valeurs.
07Questions fréquentes
Comment concaténer du texte dans Excel ?
Concaténer, c'est mettre bout à bout plusieurs textes ou valeurs dans une seule cellule. L'opérateur & suffit dans la plupart des cas.
Quel est le piège le plus fréquent avec la concaténation ?
Le résultat est du texte. ="1"&"5" donne le texte « 15 », pas le nombre 15 : il ne s'additionne pas. Si vous fabriquez un nombre, convertissez-le avec CNUM, ou multipliez-le par 1.
La fiche « Assembler du texte » est-elle gratuite ?
Oui. La fiche est en accès libre et gratuit, sans inscription : vous pouvez la lire en ligne et télécharger sa version PDF. Elle fait partie du cours de formules Excel gratuit de mesetudesdecas.fr, qui compte 23 fiches.
Passez de la fiche à la mise en situation
Les études de cas Excel de mesetudesdecas.fr placent vos apprenants face à un vrai besoin d'entreprise : fonctions de recherche, calculs conditionnels, tableaux croisés et tableaux de bord, avec énoncé, corrigé et pas-à-pas du formateur.
Voir les études de cas ExcelToutes les fiches de formules Excel
Voir aussi le cours VBA gratuit
Fiche V1.0 | Dernière mise à jour : 30/10/2026 | Clément Delobel, formateur Excel