GAUCHE, DROITE, STXT
Isoler le code postal d'une adresse, le prénom d'un nom complet, l'année d'un numéro de dossier : les exports des logiciels mettent souvent plusieurs informations dans la même cellule. Trois fonctions découpent le texte, deux autres trouvent où couper.
Télécharger la fiche PDF gratuiteSans inscription, mise en page prête à imprimer01Définition
GAUCHE renvoie les premiers caractères d'un texte, DROITE les derniers, et STXT ceux du milieu, à partir d'une position donnée.
02Syntaxe
=GAUCHE(texte; [nb_car]) =DROITE(texte; [nb_car]) =STXT(texte; no_départ; nb_car) =NBCAR(texte) =TROUVE(texte_cherché; texte; [no_départ])
NBCAR compte les caractères d'un texte. TROUVE donne la position d'un caractère : =TROUVE(" ";"Alice Martin") renvoie 6.
03Longueur fixe
Quand l'information a toujours la même longueur, les trois fonctions suffisent.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Dossier | Année | Service | Numéro |
| 2 | 2026-RH-0457 | =GAUCHE(A2;4) | =STXT(A2;6;2) | =DROITE(A2;4) |
| 3 | 2025-CO-1203 | 2025 | CO | 1203 |
04Couper avant ou après un séparateur
Quand la longueur varie, on cherche d'abord la position du séparateur avec TROUVE.
| A | B | C | |
|---|---|---|---|
| 1 | Nom complet | Prénom | Nom |
| 2 | Alice Martin | =GAUCHE(A2;TROUVE(" ";A2)-1) | =STXT(A2;TROUVE(" ";A2)+1;100) |
| 3 | Jean-Pierre Durand | Jean-Pierre | Durand |
Le -1 retire l'espace du prénom. Pour le nom, on part juste après l'espace et on prend 100 caractères : STXT s'arrête de lui-même à la fin du texte.
Dans Excel 2024 et Microsoft 365, =TEXTE.AVANT(A2;" ") et =TEXTE.APRES(A2;" ") font la même chose sans calcul de position. Voir aussi les nouvelles fonctions.
05Sans formule : le remplissage instantané
Tapez le résultat attendu pour la première ligne, par exemple « Alice » à côté de « Alice Martin », puis appuyez sur Ctrl + E dans la cellule du dessous. Excel devine la règle et remplit toute la colonne. Pratique pour un nettoyage ponctuel, mais le résultat ne se met pas à jour si les données changent.
06Pièges à éviter
=GAUCHE("59000 Lille";5) renvoie le texte « 59000 », pas un nombre. Pour calculer avec, ou pour le comparer à un nombre dans une recherche, convertissez-le : =CNUM(GAUCHE(A2;5)).
Si une cellule ne contient pas d'espace, TROUVE renvoie #VALEUR!. Protégez la formule avec SIERREUR, par exemple =SIERREUR(GAUCHE(A2;TROUVE(" ";A2)-1);A2).
Un export peut contenir des espaces au début, à la fin ou en double, qui faussent les positions. Commencez par nettoyer avec =SUPPRESPACE(A2).
TROUVE respecte les majuscules et minuscules, CHERCHE non et accepte les jokers * et ?. Pour un séparateur comme l'espace ou le tiret, les deux donnent le même résultat.
07Questions fréquentes
Comment extraire une partie d'un texte dans Excel ?
GAUCHE renvoie les premiers caractères d'un texte, DROITE les derniers, et STXT ceux du milieu, à partir d'une position donnée.
Quel est le piège le plus fréquent avec GAUCHE, DROITE et STXT ?
Le résultat est toujours du texte. =GAUCHE("59000 Lille";5) renvoie le texte « 59000 », pas un nombre. Pour calculer avec, ou pour le comparer à un nombre dans une recherche, convertissez-le : =CNUM(GAUCHE(A2;5)).
La fiche « GAUCHE, DROITE, STXT » est-elle gratuite ?
Oui. La fiche est en accès libre et gratuit, sans inscription : vous pouvez la lire en ligne et télécharger sa version PDF. Elle fait partie du cours de formules Excel gratuit de mesetudesdecas.fr, qui compte 23 fiches.
Passez de la fiche à la mise en situation
Les études de cas Excel de mesetudesdecas.fr placent vos apprenants face à un vrai besoin d'entreprise : fonctions de recherche, calculs conditionnels, tableaux croisés et tableaux de bord, avec énoncé, corrigé et pas-à-pas du formateur.
Voir les études de cas ExcelToutes les fiches de formules Excel
Voir aussi le cours VBA gratuit
Fiche V1.0 | Dernière mise à jour : 30/10/2026 | Clément Delobel, formateur Excel