Formules Excel | Versions

Les nouvelles fonctions d'Excel

Gratuit, sans inscription Niveau 3 / 3 | Avancé Lecture 10 min V1.0 | 30/10/2026

Excel a plus changé depuis 2020 qu'au cours des quinze années précédentes. Les dernières fonctions savent analyser du texte avec des expressions régulières et produire un tableau croisé dynamique en une formule. Cette fiche présente les plus utiles, et rappelle une ancienne fonction encore méconnue : AGREGAT.

Télécharger la fiche PDF gratuiteSans inscription, mise en page prête à imprimer

01Définition

En une phrase

Depuis Excel 2021, les formules peuvent renvoyer plusieurs valeurs qui débordent sur les cellules voisines. Cette évolution a permis une nouvelle génération de fonctions : filtrer, trier, découper du texte, regrouper des données, sans macro ni tableau croisé.

02Panorama des fonctions récentes

Fonction	Rôle	Disponible dans
FILTRE, TRIER, UNIQUE	Extraire, trier, dédoublonner	Excel 2021 et suivants
RECHERCHEX, EQUIVX	Rechercher sans les limites de RECHERCHEV	Excel 2021 et suivants
SEQUENCE, LET	Générer une suite, nommer un calcul intermédiaire	Excel 2021 et suivants
TEXTE.AVANT, TEXTE.APRES, FRACTIONNER.TEXTE	Découper un texte	Excel 2024 et Microsoft 365
ASSEMB.V, ASSEMB.H, CHOISIRCOLS, CHOISIRLIGNES	Empiler et remodeler des tableaux	Excel 2024 et Microsoft 365
LAMBDA	Créer ses propres fonctions, sans VBA	Excel 2024 et Microsoft 365
REGEXTEST, REGEXEXTRACT, REGEXREPLACE	Expressions régulières	Microsoft 365 uniquement
GROUPER.PAR, PIVOTER.PAR	Tableaux croisés en formule	Microsoft 365 uniquement

03Les fonctions REGEX

Une expression régulière décrit un motif de texte : « 5 chiffres », « un e-mail », « tout ce qui est entre parenthèses ». Trois fonctions l'utilisent :

Syntaxe

=REGEXTEST(texte; modèle; [respect_casse])
=REGEXEXTRACT(texte; modèle; [mode_renvoi]; [respect_casse])
=REGEXREPLACE(texte; modèle; remplacement; [occurrence]; [respect_casse])

Motif	Signification
`\d`	Un chiffre
`\d{5}`	Exactement cinq chiffres
`[A-Z]`	Une lettre majuscule
`\s+`	Une ou plusieurs espaces
`^` et `$`	Le début et la fin du texte
`.+`	N'importe quels caractères, au moins un

Extraire le code postal d'une adresse

	A	B
1	Adresse	Code postal
2	12 rue Nationale 59000 Lille	`=REGEXEXTRACT(A2;"\d{5}")`
3	3 place Bellecour, 69002 Lyon	69002

Vérifier qu'une cellule ressemble à un e-mail : VRAI ou FAUX

=REGEXTEST(A2;"^[^@\s]+@[^@\s]+\.[a-z]{2,}$")

Remplacer les espaces multiples par une seule espace

=REGEXREPLACE(A2;"\s+";" ")

Garder uniquement les chiffres d'un numéro de téléphone

=REGEXREPLACE(A2;"\D";"")

💡 AstucePas besoin de tout connaître

Quatre ou cinq motifs couvrent l'essentiel des besoins. Pour un motif plus complexe, décrivez ce que vous voulez à un assistant IA, puis testez le résultat sur quelques lignes avant de recopier la formule.

04GROUPER.PAR et PIVOTER.PAR

Ces deux fonctions produisent en une formule ce que fait un tableau croisé dynamique : regrouper et totaliser. Le résultat se met à jour dès que les données changent, sans bouton Actualiser.

Syntaxe simplifiée

=GROUPER.PAR(champs_lignes; valeurs; fonction)
=PIVOTER.PAR(champs_lignes; champs_colonnes; valeurs; fonction)

Ventes en A1:D6, total par région en F2

	A	B	C	D	F
1	Date	Région	Commercial	Montant	Résultat
2	12/01/2026	Nord	Alice	1 200 €	`=GROUPER.PAR(B2:B6;D2:D6;SOMME)`
3	25/01/2026	Sud	Bruno	800 €	Sud
4	03/02/2026	Nord	Bruno	2 500 €	Total
5	18/02/2026	Nord	Alice	600 €
6	09/03/2026	Sud	Alice	1 900 €

La formule renvoie Nord : 4 300 €, Sud : 2 700 €, puis une ligne de total général à 7 000 €.

Régions en lignes, commerciaux en colonnes

=PIVOTER.PAR(B2:B6;C2:C6;D2:D6;SOMME)

Le troisième argument est le calcul à faire : SOMME, MOYENNE, NB, MAX... sans parenthèses. Les arguments facultatifs suivants gèrent les en-têtes, les sous-totaux, le tri et un filtre.

⚠️ PiègeMicrosoft 365 uniquement

Les fonctions REGEX, GROUPER.PAR et PIVOTER.PAR n'existent pas dans Excel 2024 ni dans les versions précédentes, qui afficheront #NOM?. Réservez-les aux fichiers utilisés par des personnes équipées de Microsoft 365, ou d'Excel pour le web.

05AGREGAT : l'ancienne fonction à connaître

AGREGAT existe depuis Excel 2010, mais elle reste méconnue. Elle fait une somme, une moyenne, un maximum... en ignorant les erreurs et les lignes masquées, là où SOMME renvoie une erreur dès qu'une cellule en contient une.

Syntaxe

=AGREGAT(no_fonction; options; réf1; ...)

Code	Fonction	Code	Option
1	MOYENNE	5	Ignorer les lignes masquées
4	MAX	6	Ignorer les erreurs
5	MIN	7	Ignorer les lignes masquées et les erreurs
9	SOMME	4	Ne rien ignorer

Un total malgré une erreur dans la colonne

	A	B
1	Produit	Marge
2	Clavier	12 €
3	Souris	#DIV/0!
4	Écran	41 €
5	Total	`=AGREGAT(9;6;B2:B4)`

Résultat : 53 €. Avec =SOMME(B2:B4), on obtiendrait #DIV/0!.

06Pièges à éviter

⚠️ PiègePartager un fichier avec des fonctions récentes

Une cellule qui utilise une fonction absente de la version du destinataire affiche #NOM?. Avant d'envoyer un classeur, consultez la fiche versions d'Excel.

⚠️ PiègeLes antislashs des expressions régulières

Dans un motif, \d désigne un chiffre et \. un point. Oublier l'antislash change le sens : . seul veut dire « n'importe quel caractère ».

⚠️ PiègeCorriger la zone de débordement

Dans le résultat d'une formule qui déborde, seule la première cellule contient la formule. Les autres sont grisées dans la barre de formule et ne se modifient pas une par une.

07Questions fréquentes

Quelles sont les nouvelles fonctions d'Excel ?

Depuis Excel 2021, les formules peuvent renvoyer plusieurs valeurs qui débordent sur les cellules voisines. Cette évolution a permis une nouvelle génération de fonctions : filtrer, trier, découper du texte, regrouper des données, sans macro ni tableau croisé.

Quel est le piège le plus fréquent avec les nouvelles fonctions ?

Microsoft 365 uniquement. Les fonctions REGEX, GROUPER.PAR et PIVOTER.PAR n'existent pas dans Excel 2024 ni dans les versions précédentes, qui afficheront #NOM?. Réservez-les aux fichiers utilisés par des personnes équipées de Microsoft 365, ou d'Excel pour le web.

La fiche « Les nouvelles fonctions d'Excel » est-elle gratuite ?

Oui. La fiche est en accès libre et gratuit, sans inscription : vous pouvez la lire en ligne et télécharger sa version PDF. Elle fait partie du cours de formules Excel gratuit de mesetudesdecas.fr, qui compte 23 fiches.

Pour les formateurs

Passez de la fiche à la mise en situation

Les études de cas Excel de mesetudesdecas.fr placent vos apprenants face à un vrai besoin d'entreprise : fonctions de recherche, calculs conditionnels, tableaux croisés et tableaux de bord, avec énoncé, corrigé et pas-à-pas du formateur.

Voir les études de cas Excel

Voir aussi

VersionsLes versions d'Excel Tableaux dynamiquesFILTRE TexteGAUCHE, DROITE, STXT

Toutes les fiches de formules Excel

Voir aussi le cours VBA gratuit

Fiche V1.0 | Dernière mise à jour : 30/10/2026 | Clément Delobel, formateur Excel