La fonction UNIQUE
La liste des clients, des régions ou des produits d'un tableau, sans doublons et toujours à jour : avant, il fallait un tableau croisé ou l'outil Supprimer les doublons, à refaire à chaque ajout. La fonction UNIQUE le fait en une formule.
Télécharger la fiche PDF gratuiteSans inscription, mise en page prête à imprimer01Définition
UNIQUE renvoie la liste des valeurs différentes d'une plage, chacune une seule fois, dans l'ordre de leur première apparition.
02Syntaxe
=UNIQUE(tableau; [par_col]; [exactement_une_fois])Le troisième argument, mis à VRAI, ne garde que les valeurs qui apparaissent une seule fois dans la liste.
03Exemple
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Date | Région | Commercial | Montant | Commerciaux | |
| 2 | 12/01/2026 | Nord | Alice | 1 200 € | =UNIQUE(C2:C6) | |
| 3 | 25/01/2026 | Sud | Bruno | 800 € | Bruno | |
| 4 | 03/02/2026 | Nord | Bruno | 2 500 € | ||
| 5 | 18/02/2026 | Nord | Alice | 600 € | ||
| 6 | 09/03/2026 | Sud | Alice | 1 900 € |
04Avec d'autres fonctions
=TRIER(UNIQUE(C2:C6))
=NBVAL(UNIQUE(C2:C6))
=UNIQUE(B2:C6)
05Un tableau de synthèse qui s'agrandit seul
La zone de débordement d'une formule se désigne avec le signe # : F2# veut dire « toute la liste qui part de F2 ». On peut ainsi construire une synthèse dont le nombre de lignes suit les données.
=UNIQUE(C2:C6) =SOMME.SI.ENS(D2:D6;C2:C6;F2#)
La formule en G2 déborde elle aussi : un total par nom de la liste. Ajoutez un commercial dans les données, une ligne apparaît dans la synthèse.
Dans Données > Validation des données > Liste, indiquez la source =$F$2# : la liste déroulante contient toujours les valeurs à jour, sans doublons.
06Pièges à éviter
Si la plage contient des cellules vides, UNIQUE renvoie une ligne avec 0. Excluez-les avec FILTRE : =UNIQUE(FILTRE(C2:C100;C2:C100<>"")).
« Alice », « alice » et « Alice » suivi d'une espace : UNIQUE considère les deux premières comme identiques, mais la troisième comme différente. Nettoyez la colonne avec SUPPRESPACE avant.
UNIQUE existe dans Excel 2021, Excel 2024 et Microsoft 365. Dans les versions précédentes, utilisez Données > Supprimer les doublons sur une copie, ou un tableau croisé dynamique.
07Questions fréquentes
Comment extraire une liste sans doublons avec une formule Excel ?
UNIQUE renvoie la liste des valeurs différentes d'une plage, chacune une seule fois, dans l'ordre de leur première apparition.
Quel est le piège le plus fréquent avec la fonction UNIQUE ?
Les cellules vides. Si la plage contient des cellules vides, UNIQUE renvoie une ligne avec 0. Excluez-les avec FILTRE : =UNIQUE(FILTRE(C2:C100;C2:C100<>"")).
La fiche « UNIQUE » est-elle gratuite ?
Oui. La fiche est en accès libre et gratuit, sans inscription : vous pouvez la lire en ligne et télécharger sa version PDF. Elle fait partie du cours de formules Excel gratuit de mesetudesdecas.fr, qui compte 23 fiches.
Passez de la fiche à la mise en situation
Les études de cas Excel de mesetudesdecas.fr placent vos apprenants face à un vrai besoin d'entreprise : fonctions de recherche, calculs conditionnels, tableaux croisés et tableaux de bord, avec énoncé, corrigé et pas-à-pas du formateur.
Voir les études de cas ExcelToutes les fiches de formules Excel
Voir aussi le cours VBA gratuit
Fiche V1.0 | Dernière mise à jour : 30/10/2026 | Clément Delobel, formateur Excel